Gå til innholdet

Cookie-innstillinger

Velg hvilke typer cookies du tillater. Du kan når som helst endre valget via Cookie-innstillinger nederst på hver side. Personvernerklæring

Nødvendige

Alltid på

Trengs for å logge inn, beholde handlekurven og huske valgene dine. Disse er alltid på.

Hvilke cookies?
  • weboke_sessie, weboke_klant, weboke_remember: økten din og at du forblir innlogget
  • weboke_basket: handlekurven din
  • wkBtwIncl: visning av priser med eller uten mva.
  • wok_cookies: cookievalget ditt, 12 måneder

Måler hvilken annonse som fører til et besøk eller en bestilling, slik at vi ikke betaler for annonser som ikke gir noe.

Hvilke cookies?
  • Google Ads via Google Tag Manager (_gcl_au, _gcl_aw), opptil 90 dager
  • OpenAI Ads, annonser i ChatGPT
  • wok_aff: hvilken partner som henviste deg til oss (partnerprogram), 60 dager

4,6

Land og språk

Hvert land har sin egen nettside, med priser og mva. for det landet.

Vis

Sammenligne to lister: hvem står i den ene, men ikke i den andre?

Medlemslisten mot betalingene, fjorårets kunder mot årets, lagerlisten mot bestillingen: du vil vite hvem som står i den ene listen og ikke i den andre. Finne og slette dupliserte kunder finner duplikater i én liste. Her sammenligner du to lister med hverandre.

Som eksempel bruker vi Bakkerij De Korenaar med to regneark: Klanten2025 med fjorårets e-postadresser i A2:A8, og Klanten2026 med årets i A2:A7.

Metode 1: en hjelpekolonne med borte eller blir

Skriv inn dette i B2 på regnearket Klanten2025:

=HVIS(ANTALL.HVIS(Klanten2026!$A$2:$A$7;A2)=0;"borte";"blir")

Dra formelen ned til den siste kunden. ANTALL.HVIS teller hvor mange ganger adressen forekommer i listen for 2026. Er tallet 0, er kunden borte. Deretter kan du filtrere eller sortere på kolonne B (se Sortering og filtrering).

Dollartegnene er viktige: uten dollartegn flytter området i den andre listen seg når du drar formelen ned, og de øverste adressene faller ut nederst.

Metode 2: en liste med bare forskjellene

På et eget regneark lager FILTRER en liste over alle kunder som har falt fra, i én operasjon:

=FILTRER(Klanten2025!A2:A8;ANTALL.HVIS(Klanten2026!A2:A7;Klanten2025!A2:A8)=0;"ingen borte")

Her får ANTALL.HVIS en hel liste som andre argument og teller for hver adresse fra 2025 samtidig. FILTRER beholder adressene der resultatet er 0. De nye kundene finner du ved å bytte om listene:

=FILTRER(Klanten2026!A2:A7;ANTALL.HVIS(Klanten2025!A2:A8;Klanten2026!A2:A7)=0;"ingen nye")

Kunder som har falt fra og nye kunder side om side
Kunder som har falt fra (1) og nye kunder (2), hver med én FILTRER-formel

Hvem som bare står i én av de to listene, nye eller borte, får du med:

=UNIK(VSTAKK(Klanten2025!A2:A8;Klanten2026!A2:A7);;1)

VSTAKK setter de to listene under hverandre. UNIK med 1 som tredje argument beholder bare verdiene som forekommer nøyaktig én gang. Står en adresse allerede to ganger i én liste, gjør du først den listen unik: =UNIK(VSTAKK(UNIK(Klanten2025!A2:A8);UNIK(Klanten2026!A2:A7));;1).

Metode 3: farger i stedet for lister

  1. Merk adressene på regnearket Klanten2025, A2:A8.
  2. Velg Hjem på fanen Conditional formatting, New rule, typen Formula.
  3. Skriv inn =ANTALL.HVIS(Klanten2026!$A$2:$A$7;$A2)=0, velg en fyllfarge og klikk på OK.

En referanse til et annet regneark i en formateringsregel fungerer helt fint i Euro-Office. I eldre Excel-versjoner måtte det gjøres via et definert navn.

Kunder som har falt fra, fargelagt
Adresser som ikke lenger finnes i 2026, blir oransje. Kolonne B sier borte eller blir

Fallgruver

  • Mellomrom: "info@dekorenaar.nl " med et mellomrom bak er en annen adresse for regnearket. Rydd først bort mellomrom med TRIMME i en hjelpekolonne.
  • Tomme celler i et område teller også som verdi. Ta derfor bare med radene som inneholder data, eller filtrer bort tomme celler med <>"".
  • Tall mot tekst: sammenligner du kundenumre, og nummeret står som tekst (venstrejustert i cellen) i den ene listen og som tall i den andre, finner de ikke hverandre. Se FINN.RAD gir #N/A: slik løser du det.
  • Ikke skriv SANN uten parenteser som tredje argument i UNIK. Euro-Office godtar bare TRUE, SANN() eller 1 (se Overføre formler fra Excel: norske funksjonsnavn og semikolon).

Et øyeblikk …

Sett opp domenene dine

Ordne for hvert domene navnetjenerne, koblingen til hostingen din og hvem som blir innehaver.

Laster inn domenene dine…