Gå til innholdet

Cookie-innstillinger

Velg hvilke typer cookies du tillater. Du kan når som helst endre valget via Cookie-innstillinger nederst på hver side. Personvernerklæring

Nødvendige

Alltid på

Trengs for å logge inn, beholde handlekurven og huske valgene dine. Disse er alltid på.

Hvilke cookies?
  • weboke_sessie, weboke_klant, weboke_remember: økten din og at du forblir innlogget
  • weboke_basket: handlekurven din
  • wkBtwIncl: visning av priser med eller uten mva.
  • wok_cookies: cookievalget ditt, 12 måneder

Måler hvilken annonse som fører til et besøk eller en bestilling, slik at vi ikke betaler for annonser som ikke gir noe.

Hvilke cookies?
  • Google Ads via Google Tag Manager (_gcl_au, _gcl_aw), opptil 90 dager
  • OpenAI Ads, annonser i ChatGPT
  • wok_aff: hvilken partner som henviste deg til oss (partnerprogram), 60 dager

4,6

Land og språk

Hvert land har sin egen nettside, med priser og mva. for det landet.

Vis

Summer bare de filtrerte radene, også med en ekstra betingelse

Du filtrerer en salgsliste på én kategori, men totalen under viser fortsatt beløpet for alle radene. Det stemmer: SUMMER tar også med radene som filteret skjuler. Vil du bare summere det du ser, bruker du DELSUM. Og vil du ha en ekstra betingelse innenfor de filtrerte radene, eller hoppe over feilverdier, finnes det to nyttige formler til.

Som eksempel bruker vi salgslisten til Bloemisterij Het Zonnetje: i A datoen, i B produktet, i C kategorien og i D beløpet, fra rad 2 til og med 300. Det er et filter på overskriftsraden (se Sortering og filtrering).

Hvor plasserer du formlene?

Ikke under listen: en formel rett under listen kan selv bli skjult når du filtrerer, og flytte seg når du sorterer. Men heller ikke hvor som helst ved siden av listen: et filter skjuler hele rader, så en formel i F3 forsvinner også hvis rad 3 filtreres bort. Plasser dem derfor i overskriftsraden (rad 1, ved siden av overskriftene), eller på et eget regneark. I eksempelet står de i rad 1, fra kolonne F.

Summen av de synlige radene

=DELSUM(109;D2:D300)

Det første tallet velger beregningen. 9 er summen, det er 109 også, med én forskjell: 109 hopper også over rader du har skjult manuelt (høyreklikk, Skjul). 9 hopper bare over rader som filteret skjuler. Bruk derfor 109 hvis du vil summere det du ser.

BeregningFiltrertOgså skjult manuelt
Sum9109
Antall utfylte celler3103
Gjennomsnitt1101
Maksimum4104

Antall synlige rader teller du med =DELSUM(103;B2:B300).

DELSUM summerer bare de synlige radene
Filtrert på Buketter: DELSUM(109;...) i G1 summerer bare de synlige beløpene i kolonnen Beløp (1); nederst står det 40 av 83 poster filtrert. I K1 formelen med FORSKYVNING (#NUM!), i M1 SUMMER.HVIS.SETT med hjelpekolonnen Synlig

Synlig og en ekstra betingelse

Du har filtrert på kategorien Buketter og vil innenfor den bare summere sørgebindingene. SUMMER.HVIS.SETT tar ikke hensyn til filteret, og DELSUM har ingen betingelse. På nettet finner du en formel for dette med SUMMERPRODUKT, DELSUM og FORSKYVNING. Den gir feilverdien #NUM! i Euro-Office. Med en hjelpekolonne går det derimot, og enklere:

  1. Lag en kolonne Synlig ved siden av listen, her kolonne E. Merk E2:E300, skriv =DELSUM(103;D2) og trykk Ctrl+Enter. Hver rad får 1 så lenge den er synlig, og 0 hvis filteret skjuler den.
  2. Summer med SUMMER.HVIS.SETT og ta med hjelpekolonnen som ekstra betingelse: =SUMMER.HVIS.SETT(D2:D300;B2:B300;"Sørgebinding";E2:E300;1).

Endrer du filteret, beregnes hjelpekolonnen og summen på nytt med en gang.

Hopp over feilverdier

Står det en #N/A eller #DIV/0! et sted i kolonnen, gir SUMMER og DELSUM også en feilverdi. MENGDE kan hoppe over feil:

=MENGDE(9;7;D2:D300)

9 er igjen summen, og 7 betyr: hopp over både skjulte rader og feilverdier.

Fallgruver

  • Skjulte kolonner telles med: DELSUM ser bare på skjulte rader.

Et øyeblikk …

Sett opp domenene dine

Ordne for hvert domene navnetjenerne, koblingen til hostingen din og hvem som blir innehaver.

Laster inn domenene dine…